Kliknij na graf aby pobrać źródło w formacie Turtle

W celu zdefiniowania operacji filtrowania w danym zapytaniu stosujemy operator FILTER. Zacznijmy od czegoś prostego, np.: znajdźmy takie węzły które mają dla predykatu :e wartość literału większą od 5, a dla predykatu :j datę (jako wartość literału) po 1 marca 2010. Ponieważ nasz RDF nie ma jawnie określonych typów literałów zastosowaliśmy rzutowanie na datę (xsd:dateTime) oraz liczbę całkowitą (xsd:integer).

PREFIX    : <http://www.semanticschool.com/>
PREFIX xsd:	<http://www.w3.org/2001/XMLSchema#>
SELECT ?x
WHERE { ?x :j ?date;
           :e ?value.
        FILTER ( xsd:dateTime(?date) > xsd:dateTime("2010-03-01T00:00:00Z") &&
                 xsd:integer(?value) > 5 ) }

W wyniku otrzymamy: ?x = :B. W filtrach możemy również używać wyrażenia regularne. Jeżeli np. interesują nas te węzły, które mówią o tym, że Ala coś ma, to zapiszemy to następująco:

PREFIX :      <http://www.semanticschool.com/>
SELECT ?x
WHERE { ?x :e ?value.
        FILTER regex( ?value, "[Aa]la ma \\S+" ) }

W wyniku otrzymamy ?x = :C oraz ?x = :E. Zauważyliście zapewne, że zapisaliśmy Ala jako "[Aa]la" - to wyrażenie umożliwia nam wybranie tych fraz które zawierają zarówno Ala jak i ala. Jeżeli wielkość liter nie jest dla nas istotna w całej frazie, możemy skorzystać flagi "i", która mówi procesorowi wyrażeń regularnych, że ma ignorować wielkość liter:

PREFIX :      <http://www.semanticschool.com/>
SELECT ?x
WHERE { ?x :e ?value.
        FILTER regex( ?value, "ala ma \\S+", "i" ) }

Kliknij na graf aby pobrać źródło w formacie Turtle

Do dyspozycji mamy zestaw funkcji testujących właściwości podanych węzłów w grafie RDF:

• isIRI oraz isURI - sprawdza czy podany argument jest zasobem identyfikowanym przez URI/IRI (tzn. nie jest literałem albo bnodem).
• isBlank - sprawdza czy podany argument jest bnodem (nienazwany węzeł).
• isLiteral - sprawdza czy podany argument jest literałem.
• sameTerm - sprawdza czy podane dwa argumenty są tym samym zasobem lub literałem (zobacz http://www.w3.org/TR/rdf-concepts/ po dodatkowe informacje)
• langMatches - sprawdza czy znacznik języka literału podanego jako pierwszy argument znajduje się w zakresie języków podanym w drugim argumencie; jako drugi parametr możemy również podać "*" do oznaczenia każdego niepustego znacznika języka. Więcej na temat porównania znaczników jezyka pod adresem http://www.ietf.org/rfc/rfc4647.txt.
• możemy również porównać dwa węzły za pomocą znaku = (zobacz http://www.w3.org/TR/rdf-sparql-query/#func-RDFterm-equal po więcej informacji)

Oraz zestaw funkcji za pomocą, których możemy przekształcać podane węzły w grafie RDF do postaci ciągu znaków

• str - zwraca ciag znaków reprezentujący dany zasób; np. w przypadku literału będzie to część literału bez znacznika języka czy typu
• lang - zwraca znacznik języka podanego literału (jeśli jest określony)
• datatype - zwraca znacznik typu podanego literału (jeśli jest określony)

Dodakowo, poszczególne wyrażenia w ramach jednej frazy FILTER możemy łączyć za pomocą operatorów logicznych AND (wyrażanego jako &&) oraz OR (wyrażanego jako ||).

A teraz czas na kilka przykładów.

Szukamy zasobów "wkazujących" na węzeł :B w naszym grafie, które są identyfikowane przez URI (a nie przez bnode).

PREFIX    : <http://www.semanticschool.com/>
SELECT ?x
WHERE { ?x ?p :E.
        FILTER ( isBlank(?x) ) }

Szukamy tych zasobów które wskazują na :E i są bnodami

PREFIX    : <http://www.semanticschool.com/>
SELECT ?x
WHERE { ?x :g ?y.
        FILTER ( isLiteral(?y) ) }

Szukamy takich zasobów które wskazują na ten sam inny zasób.

PREFIX    : <http://www.semanticschool.com/>
SELECT ?x ?y
WHERE { ?x :g ?px.
        ?y :e ?py.
        FILTER ( sameTerm(?px, ?py) ) }

Pytanie: ile bedzie par wyników dla jeżeli :g, :e zastąpimy przez ?g, ?e ?

Szukamy zasobów wskazujących na literały napisane po Hiszpańsku.

PREFIX    : <http://www.semanticschool.com/>
SELECT ?x
WHERE { ?x :e ?l.
        FILTER ( langMatches( lang(?l), "ES") ) }

Pytanie: ile będzie wyników jeżeli będziemy szukali zasobów w dowolnym języku ?

Szukamy takich zasobów które wskazują na literały nie będące określeniem czasu.

PREFIX xsd:	<http://www.w3.org/2001/XMLSchema#>
SELECT ?x ?l
WHERE { ?x ?p ?l.
        FILTER ( datatype(?l) != xsd:dateTime  ) }

Na zakończenie trochę bardziej skomplikowany przykład: szukamy takich par różnych zasobów, które wskazują na ten sam literał, oraz dla których dla pierwszego zasobu reprezentacja URI w postaci ciągu znaku występuje w sortowaniu alfabetycznym przed reprezentacja URI drugiego zasobu.

SELECT ?x ?y
WHERE { ?x ?p1 ?l1.
        ?y ?p2 ?l2.
        FILTER ( isLiteral(?l1) &&
                      isLiteral(?l2) &&
                      ?l1 = ?l2 &&
                      ?x != ?y &&
                      str(?x) > str(?y) ) }

Czym są literały? Służą one do zapisu wartości liczbowych, dat, nazw, itp. w postaci ciągu znaków (reprezentacji leksykalnej).

Jednym z oczywistych zastosowań literałów jest dostarczanie etykiet do zasobów reprezentowanych przez URI, tak aby mogły być one prezentowane w sposób zrozumiały ludziom a nie tylko maszynom. Ponieważ Sieć Semantyczna była budowana od początku z myślą o międzynarodowej społeczności, możliwe jest przypisanie znacznika języka (ang. language tag) do literału. Znaczniki języka (zdefiniowane w specyfikacji RFC 3306) wyrażone są w postaci zestawu dwuliterowych etykiet, zapisanych małymi literami alfabetu łacińskiego, oddzielonych myślnikiem (-). Warto zwrócić uwagę na subtelną różnicę w zapisie znaczników języka w porównaniu do definicji lokalizacji (ang. locale) używanej powszechnie w procesie internacjonalizacji treści. Przykładem znacznika języka może być: "en" lub "pl-pl".

Jak widzieliśmy na przykładach w poprzednich artykułach, literały mogą również służyć do wyrażania ilości. Jednak jak to zwykle bywa z maszynami, należy maszynom powiedzieć jak należy interpretować wartości liczbowe, tak aby nie pomyliły ich z np. datami. Do tego celu służą tzw. typowane literały (ang. typed literals). Specyfikacja RDF przewiduje możliwość dołączenia typu danych (ang. datatype) literału zapisanego w postaci referencji URI do definicji typu. Zazwyczaj (w 99% przypadków) spotyka się definicje typów ze specyfikacji schematu XML (ang. XML Schema), np: xsd:boolean, xsd:int, itp. Specyfikacja RDF przewiduje również specjalny typ danych do osadzania dokumentu XML jako literału, służy do tego typ rdf:XMLLiteral. Ponownie jak poprzednio, proszę o informację w komentarzach jeżeli chcielibyście dowiedzieć się więcej na temat samych typów zdefiniowanych z specyfikacji schematu XML.

Czas na przykład: chcemy podać nazwę serwisu http://www.semanticschool.com/ po angielsku i po polsku, oraz datę od kiedy serwis istnieje.

Wersja NTriples wyglądałaby następująco:

<http://www.semanticschool.com> <http://purl.org/dc/terms/date> "2009-09-21"^^<http://www.w3.org/2001/XMLSchema#date> .
<http://www.semanticschool.com> <http://purl.org/dc/terms/title> "Szkoła Web 3.0"@pl .
<http://www.semanticschool.com> <http://purl.org/dc/terms/title> "School of Semantics"@en .

Turtle:

@prefix dc: <http://purl.org/dc/terms/> .

<http://www.semanticschool.com> dc:title "Szkoła Web 3.0"@pl , "School of Semantics"@en ;
	                        dc:date "2009-09-21"^^<http://www.w3.org/2001/XMLSchema#date> .

i na koniec RDF/XML:

<?xml version="1.0" encoding="UTF-8"?>
<rdf:RDF
	xmlns:rdf="http://www.w3.org/1999/02/22-rdf-syntax-ns#"
	xmlns:dc="http://purl.org/dc/terms/">

<rdf:Description rdf:about="http://www.semanticschool.com">
	<dc:title xml:lang="pl">Szkoła Web 3.0</ns2:title>
	<dc:title xml:lang="en">School of Semantics</ns2:title>
	<dc:date rdf:datatype="http://www.w3.org/2001/XMLSchema#date">2009-09-21</ns2:date>
</rdf:Description>

</rdf:RDF>

Wiem co masz na myśli

O ile lata sukcesów i porażek badań nad Sztuczną Inteligencją (ang. Artificial Intelligence) przyniosły bardziej złą sławę niż konkretne rezultaty, to należy pamiętać, że ludzie pracujący nad Siecią Semantyczną odcinają się od sztucznej inteligencji, proponując w zamian dość radykalnie różne podejście: przetwarzanie znaczeniowe a nie numeryczne.

Oczywiście wymaga to również odmiennego sposobu reprezentacji informacji: jest nią RDF (Resource Description Framework). Zanim omówimy czym jest RDF, małe ćwiczenie: postarajcie się opisać krzesło (np. z obrazka poniżej) używając do tego jak najprostszych zdań.

Krzesło: jak je opiszesz?

I jak? Udało się? Oto kilka zdań które mi przyszły do głowy:

• To jest krzesło.
• Jest zrobione z drewna i skóry.
• Posiada oparcie i nogi.
• Ma cztery nogi.
• Służy do siedzenia.
• Wykonane jest przez stolarza.

Możemy też dalej rozszerzać nasz opis:

• Stolarz wykonuje krzesła.
• Mężczyzna siedzi na krześle.
• Stolarz i mężczyzna są ludźmi.

I oczywiście moglibyśmy kontynuować nasz opis w nieskończoność. To co powstaje w naszej głowie to mapa myśli (ang. mind map). Jeżeli pominiemy restrykcje i wytyczne narzucone przez technikę tworzenia map myśli, to nasz opis krzesła możemy przedstawić następująco.

Pojęcie "krzesło" opisane jako mapa myśli

Tym samym stworzyliśmy nasz pierwszy opis w RDF.

Jak to możliwe? Otóż RDF jest właśnie językiem reprezentacji informacji zapisanej w grafie (skierowanym). Każde proste zdanie (w języku naturalnym) odpowiada jednej krawędzi w grafie, tj. wyróżniamy 3 elementy każdego zdania RDF (ang. RDF statement):

• podmiot (ang. subject) to wierzchołek, czyli zasób (ang. resource), w którym zaczyna się dana krawędź,
• predykat (ang. predicate) nazywa daną krawędź w grafie,
• obiekt (ang. object) to drugi wierzchołek, zasób lub literał (ang. literal), w którym kończy się dana krawędź.

Na przykład nasze zdania możemy zapisać następująco, wyróżniając poszczególne elementy zdania RDF:

• [Krzesło] [posiada] [oparcie].
• [Krzesło] [służy do] [siedzenia].
• [Krzesło] [wykonane jest przez] [stolarza].
• [Stolarz] [wykonuje] [krzesła].
• [Mężczyzna] [siedzi na] [krześle].

Jest jednak kilka zdań, których zapis nie jest aż tak oczywisty.

• "Jest zrobione z drewna i skóry" - możemy zapisać jako dwa zdania:
  • [Krzesło] [jest zrobione z] [drewna].
  • [Krzesło] [jest zrobione ze] [skóry].
• "Posiada cztery nogi." - tutaj ujawnia się ciekawa właściwość RDF, tzw. reifikacja (ang. reification), czyli wypowiadanie zdania o zdaniu. W tym przypadku będzimy potrzebowali dwóch zdań RDF do zapisania tego przykładu (tak naprawdę będziemy potrzebowali aż 6 zdań, ale o tym w jednym z kolejnych artykułów):
  • [Krzesło] [ma] [nogi].
  • [W powyższym zdaniu] [jest nóg sztuk] "4".
• Zadania z "to jest" wymagają specjalnego predykatu do określenia klasy, tzn. typu, opisywanego zasobu. Ten predykat to "rdf:type" i jest jednym z istotnych elementów opisu RDF (więcej na ten temat niedługo):
  • [Nasze krzesło] [rdf:type] [Krzesło].
  • [Nasz mężczyzna] [rdf:type] [Człowiek].
  • [Nasz stolarz] [rdf:type] [Człowiek].

Chociaż nie potrafimy jeszcze zapisać formalnie opisu RDF (o tym w artykule o sposobach reprezentacji grafu RDF), to na zakończenie warto zapamiętać jeszcze kilka (trochę technicznych informacji, więc nie przejmujcie się jeżeli wrócimy do nich w najbliższych artykułach).

W grafie RDF występują dwa typy wierzchołków: zasoby (ang. resource) i literały (ang. literal). Zasoby są identyfikowane przez URI (patrz artykuł o semantycznym torcie), i mogą być początkiem, jak i końcem krawędzi w grafie; sama krawędź jest również identyfikowana przez URI. Literały są ciągami znaków, liczbami, datami, itp., i tym samym mogą być jedynie końcowym wierzchołkiem krawędzi.

RDF definiuje jeszcze jeden specjalny typ wierzchołka: tzw. nienazwany wierzchołek (ang. blank node). Nienazwane wierzchołki nie mogą być identyfikowane poza systemem, który przechowuje informacje o grafie. Możemy użyć ich do reprezentacji wierzchołków grafu, ale nie do reprezentacji jego krawędzi. Do nienazwanych wierzchołków jeszcze wrócimy, ale zapamiętajcie, że należy ich unikać ze wszystkich sił.